Figure 1
   BASIC Program For Computing The Coefficients of Root-Matched
             Recurrence Relations For Homogeneous ODEs

        DEFDBL A-Z
        DIM a(10), w(50), e(10), sigma(10)
        sumto = 50

  5     INPUT "enter n"; n
        IF n < 0 GOTO 100
        INPUT "enter dt"; dt

        FOR i = 0 TO n
        PRINT USING "enter a#"; i
        INPUT a(i)
        NEXT i

        FOR i = 1 TO sumto
        IF (i <= n) THEN w(0) = i: low = n - i ELSE low = 0
        w(i) = 0#
        FOR j = low TO n - 1
        w(i) = w(i) + a(j) * w(i + j - n)
        NEXT j
        w(i) = -w(i) / a(n)
        NEXT i

        FOR i = 1 TO n
        e(i) = 0# : f = 1#
        FOR j = 0 TO sumto
        e(i) = e(i) + f * w(j)
        f = f * i * dt / (j + 1)
        NEXT j
        NEXT i

        sigma(0) = 1#
        FOR i = 1 TO n
        sigma(i) = 0#
        FOR j = 1 TO i
        sigma(i) = sigma(i) + e(j) * sigma(i - j)
        NEXT j
        sigma(i) = -sigma(i) / i
        NEXT i

        FOR i = 0 TO n
        PRINT i, sigma(i)
        NEXT i

        GOTO 5
  100   STOP
        END